dotfiles/emacs/.emacs.d/init.el

;;; init.el --- Emacs Configuration -*- lexical-binding: t; -*-

;; -------------------------------------------------------------------
;; Basic UI and Defaults
;; -------------------------------------------------------------------
(setq inhibit-startup-message t)

(scroll-bar-mode -1)
(tool-bar-mode -1)
(tooltip-mode -1)
(set-fringe-mode 10)
(menu-bar-mode -1)

(setq-default indent-tabs-mode nil)
(setq-default tab-width 4)
(setq-default standard-indent 4)

(setq scroll-margin 5)
(setq scroll-conservatively 101)

(setq visible-bell t)

(column-number-mode 1)

;; Enable line numbers exclusively in programming modes (clean Org/terminals)
(add-hook 'prog-mode-hook #'display-line-numbers-mode)

;; Clipboard settings
(setq select-enable-clipboard t)
(setq select-enable-primary t)
(setq save-interprogram-paste-before-kill t)
(setq auth-sources '("~/.authinfo"))

(add-to-list 'initial-frame-alist '(fullscreen . maximized))

;; Global Escape binding
(global-set-key (kbd "<escape>") 'keyboard-escape-quit)

;; -------------------------------------------------------------------
;; Package Management
;; -------------------------------------------------------------------
(require 'package)

(setq package-archives '(("melpa" . "https://melpa.org/packages/")
                         ("org"   . "https://orgmode.org/elpa/")
                         ("elpa"  . "https://elpa.gnu.org/packages/")))

(package-initialize)
(require 'seq)

(unless package-archive-contents
  (package-refresh-contents))

(unless (package-installed-p 'use-package)
  (package-install 'use-package))

(require 'use-package)
(setq use-package-always-ensure t)

;; -------------------------------------------------------------------
;; Appearance & Theming
;; -------------------------------------------------------------------
(use-package doom-themes
  :init (load-theme 'doom-gruvbox t))

(use-package all-the-icons)

(use-package doom-modeline
  :init (doom-modeline-mode 1)
  :custom (doom-modeline-height 15))

(use-package rainbow-delimiters
  :hook (prog-mode . rainbow-delimiters-mode))

(defvar runemacs/default-font-size 140)

(defun marc/set-font-faces ()
  "Apply font definitions to current and future frames."
  (set-face-attribute 'default nil :font "Fira Code" :height runemacs/default-font-size)
  (set-face-attribute 'fixed-pitch nil :font "Fira Code" :height 1.0)
  (set-face-attribute 'variable-pitch nil :font "Cantarell" :height 1.0 :weight 'regular))

;; Apply fonts immediately or on daemon frame creation
(if (daemonp)
    (add-hook 'after-make-frame-functions
              (lambda (frame)
                (with-selected-frame frame
                  (marc/set-font-faces))))
  (marc/set-font-faces))

;; -------------------------------------------------------------------
;; Buffer Tabs (LazyVim-style bufferline)
;; -------------------------------------------------------------------
;; Every open buffer is shown as a numbered tab in a bar at the top of
;; each window.  Click a tab, or press M-1 .. M-9 (M-0 for the tenth),
;; to switch to it.
(defvar marc/tab-line-order nil
  "Stable display order of buffers shown in the tab line.")

(defun marc/tab-line-buffers ()
  "Return live, non-hidden buffers in a stable display order."
  (setq marc/tab-line-order
        (seq-filter (lambda (b)
                      (and (buffer-live-p b)
                           (not (string-prefix-p " " (buffer-name b)))))
                    marc/tab-line-order))
  (dolist (b (buffer-list))
    (when (and (buffer-live-p b)
               (not (string-prefix-p " " (buffer-name b)))
               (not (memq b marc/tab-line-order)))
      (setq marc/tab-line-order (append marc/tab-line-order (list b)))))
  marc/tab-line-order)

(defun marc/tab-line-tab-name (buffer &optional tabs)
  "Format BUFFER's tab name as its position number plus the buffer name."
  (let* ((tabs (or tabs (funcall tab-line-tabs-function)))
         (index (1+ (or (seq-position tabs buffer #'eq) 0)))
         (name (buffer-name buffer)))
    (format "%d %s" index
            (if (> (length name) 24)
                (concat (substring name 0 23) "…")
              name))))

(defun marc/tab-line-select-numbered (n)
  "Switch to the N-th buffer tab (1-based)."
  (interactive "p")
  (let ((tabs (funcall tab-line-tabs-function)))
    (when (and (integerp n) (<= 1 n (length tabs)))
      (switch-to-buffer (nth (1- n) tabs)))))

(use-package tab-line
  :ensure nil
  :config
  (setq tab-line-tabs-function #'marc/tab-line-buffers
        tab-line-tab-name-function #'marc/tab-line-tab-name)
  (global-tab-line-mode 1)
  (dotimes (i 9)
    (let ((n (1+ i)))
      (global-set-key (kbd (format "M-%d" n))
                      (lambda () (interactive) (marc/tab-line-select-numbered n)))))
  (global-set-key (kbd "M-0")
                  (lambda () (interactive) (marc/tab-line-select-numbered 10))))

;; -------------------------------------------------------------------
;; Completion & Search (Ivy / Counsel / Swiper)
;; -------------------------------------------------------------------
(use-package command-log-mode)

(use-package ivy
  :diminish
  :bind (("C-s" . swiper)
         :map ivy-minibuffer-map
         ("TAB" . ivy-alt-done)
         ("C-l" . ivy-alt-done)
         ("C-j" . ivy-next-line)
         ("C-k" . ivy-previous-line)
         :map ivy-switch-buffer-map
         ("C-k" . ivy-previous-line)
         ("C-l" . ivy-done)
         :map ivy-reverse-i-search-map
         ("C-k" . ivy-previous-line)
         ("C-d" . ivy-reverse-i-search-kill))
  :config
  (ivy-mode 1))

(use-package ivy-rich
  :init (ivy-rich-mode 1))

(use-package counsel
  :bind (("M-x" . counsel-M-x)
         ("C-x b" . counsel-ibuffer)
         ("C-x C-f" . counsel-find-file)
         :map minibuffer-local-map
         ("C-r" . counsel-minibuffer-history))
  :config
  (setq ivy-initial-inputs-alist nil))

(use-package which-key
  :init (which-key-mode)
  :diminish which-key-mode
  :config (setq which-key-idle-delay 0.3))

(use-package helpful
  :custom
  (counsel-describe-function-function #'helpful-callable)
  (counsel-describe-variable-function #'helpful-variable)
  :bind
  ([remap describe-function] . counsel-describe-function)
  ([remap describe-command]  . helpful-command)
  ([remap describe-variable] . counsel-describe-variable)
  ([remap describe-key]      . helpful-key))

;; -------------------------------------------------------------------
;; Evil Mode (Vim Emulation) & Keybindings
;; -------------------------------------------------------------------
(use-package evil
  :demand t
  :init
  (setq evil-want-integration t)
  (setq evil-want-keybinding nil)
  (setq evil-want-C-u-scroll t)
  (setq evil-want-C-i-jump nil)
  :config
  (evil-mode 1)

  ;; Configure initial states and modes once Evil is loaded
  (evil-set-initial-state 'messages-buffer-mode 'normal)
  (evil-set-initial-state 'dashboard-mode 'normal)
  (dolist (mode '(custom-mode
                  eshell-mode
                  git-rebase-mode
                  erc-mode
                  circe-server-mode
                  circe-chat-mode
                  circe-query-mode
                  sauron-mode
                  term-mode))
    (add-to-list 'evil-emacs-state-modes mode))

  (define-key evil-insert-state-map (kbd "C-g") 'evil-normal-state)
  (define-key evil-insert-state-map (kbd "C-h") 'evil-delete-backward-char-and-join)

  ;; Use visual line motions even outside of visual-line-mode buffers
  (evil-global-set-key 'motion "j" 'evil-next-visual-line)
  (evil-global-set-key 'motion "k" 'evil-previous-visual-line))

(use-package evil-collection
  :after evil
  :demand t
  :config
  (evil-collection-init))

(use-package general
  :config
  (general-create-definer rune/leader-keys
    :prefix "C-SPC")

  (global-unset-key (kbd "C-SPC"))

  (rune/leader-keys
    "t"  '(:ignore t :which-key "toggles")
    "tt" '(counsel-load-theme :which-key "choose theme")
    "p"  '(:ignore t :which-key "projectile")
    "ps" '(rune/counsel-rg-project :which-key "search project with rg")
    "pf" '(counsel-projectile-find-file :which-key "find file in project")
    "pp" '(counsel-projectile-switch-project :which-key "switch project")
    "m"  '(:ignore t :which-key "magit")
    "mm" '(magit-status :which-key "magit status")
    "."  '(find-file :which-key "find file"))

  (general-define-key
   "C-M-j" 'counsel-switch-buffer))

;; -------------------------------------------------------------------
;; Projectile & Version Control
;; -------------------------------------------------------------------
(use-package ripgrep)
(use-package rg)

(defvar rune/counsel-rg--orig-buffer nil
  "Buffer to restore if a `rune/counsel-rg-project' session is aborted.")
(defvar rune/counsel-rg--orig-point nil
  "Point to restore if a `rune/counsel-rg-project' session is aborted.")
(defvar rune/counsel-rg--session-buffers nil
  "Value of `buffer-list' when a `rune/counsel-rg-project' session started.")

(defun rune/counsel-rg--unwind-fn ()
  "Restore the originating buffer when preview is aborted.
Always cleans up the async rg process and swiper overlays.  When
the session did not finish with RET (`ivy-exit' is not `done'),
jump back to the original buffer/point and kill file buffers that
were opened purely for preview."
  (counsel-delete-process)
  (swiper--cleanup)
  (let ((orig rune/counsel-rg--orig-buffer)
        (pt rune/counsel-rg--orig-point)
        (old-bufs rune/counsel-rg--session-buffers)
        (aborted (not (eq ivy-exit 'done))))
    (setq rune/counsel-rg--orig-buffer nil
          rune/counsel-rg--orig-point nil
          rune/counsel-rg--session-buffers nil)
    (when (and aborted orig (buffer-live-p orig))
      (with-ivy-window
        (switch-to-buffer orig)
        (when (and pt (<= pt (point-max)))
          (goto-char pt))))
    (when aborted
      (dolist (buf (seq-filter (lambda (b) (not (memq b old-bufs))) (buffer-list)))
        (when (and (buffer-live-p buf)
                   (not (eq buf orig))
                   (buffer-file-name buf)
                   (not (buffer-modified-p buf)))
          (kill-buffer buf))))))

(defun rune/counsel-rg-project ()
  "Search the current project using counsel-rg with live preview.
The highlighted candidate is shown in the current window as you
move; aborting (C-g / ESC) restores the original buffer, while RET
jumps to the selected match."
  (interactive)
  (setq rune/counsel-rg--orig-buffer (current-buffer))
  (setq rune/counsel-rg--orig-point (point))
  (setq rune/counsel-rg--session-buffers (buffer-list))
  (let ((ivy-update-fns-alist '((counsel-rg . auto)))
        (ivy-unwind-fns-alist '((counsel-rg . rune/counsel-rg--unwind-fn))))
    (counsel-rg nil (projectile-project-root))))

(use-package projectile
  :diminish projectile-mode
  :config (projectile-mode)
  :custom ((projectile-completion-system 'ivy))
  :bind-keymap
  ("C-c p" . projectile-command-map)
  :init
  (setq projectile-project-search-path 
        (seq-filter #'file-directory-p '("~/Projects" "~/repos")))
  (setq projectile-switch-project-action #'projectile-dired))

(use-package counsel-projectile
  :init
  (unless (fboundp 'projectile-ignored-files-rel)
    (defalias 'projectile-ignored-files-rel
      (if (fboundp 'projectile-ignored-files-relative)
          #'projectile-ignored-files-relative
        #'projectile-ignored-files)))
  :after (projectile counsel)
  :config (counsel-projectile-mode 1))

(use-package magit
  :commands (magit-status magit-get-current-branch)
  :custom
  (magit-display-buffer-function #'magit-display-buffer-same-window-except-diff-v1))

;; -------------------------------------------------------------------
;; Org Mode
;; -------------------------------------------------------------------
(defun marc/org-mode-setup ()
  (org-indent-mode)
  (variable-pitch-mode 1)
  (auto-fill-mode 0)
  (visual-line-mode 1)
  (setq evil-auto-indent nil)
  (setq display-line-numbers nil))

(defun marc/org-font-setup ()
  ;; Replace list item marker with bullet
  (font-lock-add-keywords 'org-mode
                          '(("^ *\\([-]\\) "
                             (0 (prog1 () (compose-region (match-beginning 1) (match-end 1) "•"))))))

  ;; Set heading levels font and size relative to base
  (dolist (face '((org-level-1 . 1.25)
                  (org-level-2 . 1.15)
                  (org-level-3 . 1.08)
                  (org-level-4 . 1.0)
                  (org-level-5 . 1.0)
                  (org-level-6 . 1.0)
                  (org-level-7 . 1.0)
                  (org-level-8 . 1.0)))
    (set-face-attribute (car face) nil :font "Cantarell" :weight 'regular :height (cdr face)))

  ;; Ensure code, tables, and metadata keep monospaced fixed-pitch font
  (dolist (face '(org-block
                  org-block-begin-line
                  org-block-end-line
                  org-code
                  org-table
                  org-verbatim
                  org-special-keyword
                  org-meta-line
                  org-checkbox
                  org-property-value
                  org-document-info-keyword))
    (set-face-attribute face nil :inherit 'fixed-pitch :font "Fira Code")))

(use-package org
  :hook ((org-mode . marc/org-mode-setup)
         (org-mode . marc/org-font-setup))
  :config
  (setq org-ellipsis " ▼"
        org-hide-emphasis-markers t)
  (setq org-agenda-files
        '("/home/mmarcos/Nextcloud/OrgVault/lists/Birthdays.org"
          "/home/mmarcos/Nextcloud/OrgVault/lists/Meetings.org"
          "/home/mmarcos/Nextcloud/OrgVault/todo.org"))
  (setq org-todo-keywords
        '((sequence "TODO(t)" "NEXT(n)" "|" "DONE(d)")
          (sequence "PLAN(p)" "READY(r)" "BLOCKED(b)" "ACTIVE(a)" "HOLD(h)" "|" "COMPLETED(c)" "KILLED(k)")))
  (setq org-agenda-start-with-log-mode t)
  (setq org-log-done 'time)
  (setq org-log-into-drawer nil))

(use-package org-bullets
  :after org
  :hook (org-mode . org-bullets-mode)
  :custom
  (org-bullets-bullet-list '("◉" "○" "●" "○" "●" "○" "●")))

;; -------------------------------------------------------------------
;; Editing
;; -------------------------------------------------------------------
(use-package blamer
  :defer 20
  :custom
  (blamer-idle-time 0.5)
  (blamer-min-offset 4)
  (blamer-view 'overlay-right)
  (blamer-type 'both)
  :custom-face
  (blamer-face ((t :foreground "#7c6f64"
                   :background nil
                   :height 0.85
                   :italic t)))
  :config
  (global-blamer-mode 1))

;; -------------------------------------------------------------------
;; LSP & Languages
;; -------------------------------------------------------------------

;; Base LSP Setup
(defun marc/lsp-mode-setup ()
  (setq lsp-headerline-breadcrumb-segments '(path-up-to-project file symbols))
  (lsp-headerline-breadcrumb-mode))

(use-package lsp-mode
  :commands (lsp lsp-deferred)
  :init
  (setq lsp-keymap-prefix "C-c l")
  :hook ((lsp-mode . marc/lsp-mode-setup)
         (lsp-mode . lsp-enable-which-key-integration)))

(use-package lsp-ui
  :hook (lsp-mode . lsp-ui-mode))

(use-package company
  :after lsp-mode
  :hook (lsp-mode . company-mode)
  :bind (:map company-active-map
              ("<tab>" . company-complete-selection))
        (:map lsp-mode-map
              ("<tab>" . company-indent-or-complete-common))
  :custom
  (company-minimum-prefix-length 1)
  (company-idle-delay 0.0))

(use-package company-box
  :hook (company-mode . company-box-mode))

;; Python
(use-package pyvenv
  :config
  (pyvenv-mode 1))

(use-package lsp-pyright
  :hook (python-mode . (lambda ()
                         (require 'lsp-pyright)
                         (lsp-deferred))))

;; Verilog
(use-package verilog-mode
  :ensure nil
  :hook (verilog-mode . lsp-deferred)
  :custom
  (verilog-auto-newline nil)
  (verilog-auto-indent-on-newline t)
  (verilog-tab-always-indent t)
  (verilog-auto-lineup nil)
  (verilog-align-typdef-words nil)
  (verilog-align-ifelse nil)
  (verilog-auto-inst-column 0)
  (verilog-auto-lineup-declarations nil)
  (verilog-indent-level 4)
  (verilog-indent-level-module 4)
  (verilog-indent-level-declaration 4)
  (verilog-indent-level-behavioral 4)
  (verilog-indent-level-directive 4)
  (verilog-cexp-indent 4)
  (verilog-case-indent 4))

(with-eval-after-load 'lsp-mode
  (lsp-register-client
   (make-lsp-client :new-connection (lsp-stdio-connection "verible-verilog-ls")
                    :major-modes '(verilog-mode)
                    :server-id 'verible-ls)))

;; Scala / Chisel
;; Chisel is a Scala DSL, so its language support comes from Metals (the
;; Scala language server).  Metals understands sbt and Mill builds, which
;; is what Chisel projects use.
(use-package scala-mode
  :interpreter ("scala" . scala-mode)
  :hook (scala-mode . lsp-deferred))

(use-package sbt-mode
  :commands (sbt-start sbt-command)
  :config
  (substitute-key-definition
   'minibuffer-complete 'sbt-completion-at-point minibuffer-local-map))

(use-package lsp-metals
  :defer t
  :init
  (setq lsp-metals-server-command
        (expand-file-name "~/.local/share/coursier/bin/metals"))
  :custom
  (lsp-metals-enable-semantic-highlighting t)
  (lsp-metals-inlay-hints-enable-inferred-types t)
  (lsp-metals-inlay-hints-enable-implicit-conversions t)
  (lsp-metals-super-method-lenses-enabled t))

;; C / C++
(use-package cc-mode
  :ensure nil
  :hook ((c-mode . lsp-deferred)
         (c++-mode . lsp-deferred))
  :custom
  (c-basic-offset 4)
  (c-default-style "linux"))

(with-eval-after-load 'lsp-mode
  (setq lsp-clients-clangd-args
        '("--background-index"
          "--clang-tidy"
          "--completion-style=detailed"
          "--header-insertion=iwyu"
          "-j=4"))
  (setq lsp-clients-clangd-executable "clangd"))

;; Assembly (asm-lsp)
(use-package asm-mode
  :ensure nil
  :hook (asm-mode . lsp-deferred))

;; YAML
(use-package yaml-mode
  :mode ("\\.ya?ml\\'" . yaml-mode))

(with-eval-after-load 'lsp-mode
  (lsp-register-client
   (make-lsp-client :new-connection (lsp-stdio-connection "asm-lsp")
                    :major-modes '(asm-mode)
                    :server-id 'asm-lsp)))

;; -------------------------------------------------------------------
;; Startup: open today's Org agenda
;; -------------------------------------------------------------------
;; A brand-new frame with no file to open (e.g. `emacsclient -c') shows
;; today's agenda.  Using `initial-buffer-choice' lets Emacs swap the
;; frame's buffer in place instead of opening a second frame.
(defun marc/agenda-buffer ()
  "Return today's Org agenda buffer, creating it if necessary."
  (require 'org-agenda)
  (org-agenda-list 1)
  (or (get-buffer org-agenda-buffer-name)
      (get-buffer-create "*scratch*")))

(setq initial-buffer-choice #'marc/agenda-buffer)

;;; init.el ends here

(custom-set-variables
 ;; custom-set-variables was added by Custom.
 ;; If you edit it by hand, you could mess it up, so be careful.
 ;; Your init file should contain only one such instance.
 ;; If there is more than one, they won't work right.
 '(org-agenda-files
   '("/home/mmarcos/Nextcloud/OrgVault/testing_tutorial/Tasks.org" "/home/mmarcos/Nextcloud/OrgVault/lists/Birthdays.org" "/home/mmarcos/Nextcloud/OrgVault/todo.org"))
 '(package-selected-packages
   '(yaml-mode haskell-mode blamer lsp-ui company-box company lsp-pyright pyvenv lsp-mode ement visual-fill-mode which-key ripgrep rg rainbow-delimiters org-bullets ivy-rich helpful general forge evil-collection doom-themes doom-modeline counsel-projectile command-log-mode all-the-icons 0x0 0blayout)))
(custom-set-faces
 ;; custom-set-faces was added by Custom.
 ;; If you edit it by hand, you could mess it up, so be careful.
 ;; Your init file should contain only one such instance.
 ;; If there is more than one, they won't work right.
 )